用MASM、TC2.0 写一个简单的x86引导程序
具体的操作过程在下边的 load.c 文件注释中有比较详细的说明。
目的：写一个引导程序和一个超简单的内核，引导成功后能在键盘上输入字符并显示
工具：masm5.0编译器，tc2.0,一个电脑（如果有virtual pc的话更可以，在上面做实验不损机子）。
所需知识：
我简单地说说电脑开机的过程吧，电脑开机后经过很复杂的过程，包括什么自检呀，bios驻入内存呀.... 最后bios把引导盘的0磁道1扇区的512字节放入内存0000:7c00开始的地方，然后把控制权交给引导程序，那一瞬间CS=0000,IP=7c00.(我想应该是这样)，然后一切就可以进入你的掌握之中了。
我们现在用汇编要写的就是7c00之后的程序，把这个程序放在第一个扇区，叫做boot,这个程序的作用是把放在第二个扇区的kernel调入内存8000:0000处并跳到那里执行。
文件：boot.asm
;file:boot.asm
;load.exe 程序将下边代码生成的二进制文件写入A盘
;的0磁道1扇区;
;开机时BIOS引导程序会自动将这个扇区的内容加载进入内存
;的07c0H处并执行它;
code segment
assume cs:code
start: ;cs=0000,ip=7c00
mov ax,offset start
add ax,07c0h ;ax加上07c0h送给ds,
mov ds,ax ;设置数据段寄存器ds,
;使得ds:0000为内存地址的0000:7c00
mov si,offset msg ;msg偏移送si
call display ;显示
;初始化 int 13h 的各寄存器,加载内核(kernel)
;(具体设置信息请查阅BIOS中断手册）
mov ax, 8000h ; kernel将要存放的内存的段地址
mov es, ax ; 传递给ES
mov bx, 0 ; kernel偏移地址为0
mov dl, 0 ; 驱动器号为0h,即A盘
mov dh, 0 ; 磁头号为0
mov ch, 0 ; 磁道号为0
mov cl, 2 ; 扇区号为2
mov al, 1 ; 要读的扇区数为1
mov ah, 2 ; 调用读磁盘的中断程序
int 13h
;内核加载完毕
mov si,offset ok ;显示ok
call display
mov bx,offset ker ;kernel 存放的是地址 8000:0000
;根据前边(es:bx)的设定。
;跳去执行内核(kernel)程序。
jmp dword ptr [bx] ;跳到bx这个指针指向的地址处。
display:
lodsb ; 装入一个字节到al
or al,al ; al=0则表明这个字符串结束
jz disend ; 跳到最后返回
mov ah, 0eh ; 0eh是显示功能号
mov bx, 7 ; 颜色
int 10h
jmp display
disend:
ret
msg db 'My Os is loading...',0 ;显示信息
ok db 'OK',13,10,0
ker dw 0,8000h ;kernel的内存地址8000:0000
code ends
end start
文件：kernel.asm
;file:kernel.asm
;load.exe 程序将下边代码生成的二进制文件写入了A盘
;的0磁道2扇区;
;在0磁道1扇区的boot代码会将此代码加载到内存中并跳
;转到对应地址去执行这段代码.
;代码功能:不断从键盘接收输入,并将其顺序显示出来.
kernel segment
assume cs:kernel
start:
mov ah,0 ;从键盘读入字符的功能
int 16h
mov ah,0eh ;显示功能
int 10h
cmp al,13 ;如果是回车则换行
jnz start
mov al,10
int 10h
jmp start ;无穷循环
kernel ends
end start